开始前三文鱼先稍微介绍一下 "WIMBOOT"

Wimboot 是 Windows 8.1 updata新增加的启动方式

主要可以进一步压缩系统档案所占用的空间, 让原本储存空间就小的平板或笔电

增加更多可以使用的空间, 下图是使用WIMBOOT技术之后的开机磁碟所占用的空间

(因为我不是刚完成安装就写了这篇教学, 刚安装完空间占用为200MB, 再加上系统WIM档占用4.35GB, 也不过是5GB不到, 跟原来安装系统的10多GB相比有明显的差异)

再来讲讲限制, 要使用WIMBOOT技术, 最大的限制是你必须使用Windows 8.1

并且将Windows 8.1 透过系统升级 KB2919355 这个更新之后才能使用上这个新的启动技术

另外据说非SSD硬碟可能在启动上面会缓慢不少, 三文鱼没有测试传统硬碟的执行效率, 只是听说~ 哈 (已经测试如下!!)

( 2014-04-24 传统硬碟使用VHD+WIMBOOT启动测试, 虽然比SSD慢了不少, 尤其是第一次启动, 但是感觉跟直接安装在硬碟使用起来没有甚么差别, 所以传统硬碟的爱用者也可以尝试看看)

 

下面是升级 KB2919355 至所需要的更新包, 在此仅提供x64的更新档位址, 请见谅!!

官方下载:  Windows8.1-KB2919442-x64.msu
                     Windows8.1-KB2919355-x64.msu

官方安装指示: 必须按照下列顺序安装这些 KB：KB2919442、KB2919355、KB2932046、KB2937592、KB2938439 和 KB2934018。

请依照官方的指示进行安装, 安装完成后, 恭喜你, 你已经拥有使用WIMBOOT启动的条件了

接下来我们要开始制作支援WIMBOOT的WIM档

为了让大家操作方便, 我们直接使用批处理来进行接下来的步骤

1. 先将下面批处理存为文字档然后将副档名改为  *.cmd

============= 添加WIMBOOT支援.cmd ============================================

@echo off

IF NOT exist install.wim ECHO 请复制原版ISO中的 install.wim 至本批次档目录后重试!!&PAUSE&GOTO EXIT
IF NOT exist Windows8.1-KB2919442-x64.msu ECHO 请确定目录中含有 Windows8.1-KB2919442-x64.msu 后重试!!&PAUSE&GOTO EXIT
IF NOT exist Windows8.1-KB2919355-x64.msu ECHO 请确定目录中含有 Windows8.1-KB2919355-x64.msu 后重试!!&PAUSE&GOTO EXIT
IF NOT exist Windows8.1-KB2932046-x64.msu ECHO 请确定目录中含有 Windows8.1-KB2932046-x64.msu 后重试!!&PAUSE&GOTO EXIT
IF NOT exist Windows8.1-KB2937592-x64.msu ECHO 请确定目录中含有 Windows8.1-KB2937592-x64.msu 后重试!!&PAUSE&GOTO EXIT

DEL /F /S /Q "%~dp0TEMP.vhd"
echo create vdisk file="%~dp0TEMP.vhd" maximum=25000 TYPE=EXPANDABLE>>"%temp%\attachvdisk.txt"
echo select vdisk file="%~dp0TEMP.vhd">>"%temp%\attachvdisk.txt"
echo attach vdisk>>"%temp%\attachvdisk.txt"
echo create partition primary>>"%temp%\attachvdisk.txt"
echo format fs=ntfs label=WIM quick>>"%temp%\attachvdisk.txt"
echo assign letter=Z>>"%temp%\attachvdisk.txt"
echo exit>>"%temp%\attachvdisk.txt"
diskpart /s "%temp%\attachvdisk.txt"
del "%temp%\attachvdisk.txt"

md Z:\mount
Dism /Mount-Image /ImageFile:install.wim /Index:1 /MountDir:Z:\mount
Dism /Add-Package /PackagePath:Windows8.1-KB2919442-x64.msu /Image:Z:\mount
Dism /Add-Package /PackagePath:Windows8.1-KB2919355-x64.msu /Image:Z:\mount
Dism /Add-Package /PackagePath:Windows8.1-KB2932046-x64.msu /Image:Z:\mount
Dism /Add-Package /PackagePath:Windows8.1-KB2937592-x64.msu /Image:Z:\mount
Dism /image:Z:\mount /Cleanup-Image /StartComponentCleanup /ResetBase
Dism /Unmount-Image /MountDir:Z:\mount /Commit
Dism /Export-Image /WIMBoot /SourceImageFile:install.wim /SourceIndex:1 /DestinationImageFile:NEW_install.wim

:EXIT

=============批处理结束!!!=================================================

2. 将刚刚下载的升级档与上面的批处理放在一起

3. 复制原版Windows 8.1 的光碟中 X:\sources\install.wim 同样放在与批处理同一个目录下

4. 接下来执行批处理, 会得到一个 NEW_install.wim 这个档案就是WIMBOOT的核心了,

(在WIMBOOT启动的系统中, 所有的档案都是以这个档案为预设的来源, 到这里已经成功的差不多了, 接下来就是让这个档案发挥启动的作用啰)

5. 选一个磁区或使用VHD虚拟的磁区来当作开机的磁碟, 我操作时是直接在SSD硬碟中分割一块8G大小的磁区来当开机磁碟(如最上面的截图), 先将下面存成批次档, 然后 注意!! 将批处理中的红字部分的X: 改成你要释放的磁碟机 假设你要释放到C磁碟就改成C: , 接著将你要转换的档案, 也就是刚刚第4步骤生成的NEW_install.wim 拖入到这个批次档, 就会开始进行档案释放 (实际上应该是将WIM里面的档案以硬连结的方式将资料连结写入硬碟)

============= 释放WIM档案至磁碟X.cmd =============================================

@echo off
Rem 用法: 拖动要生成VHD档的WIM档至此

Rem 将新生成符合WIMBOOT的WIM档挂载至 X:\
DISM /Apply-Image /ImageFile:"%~nx1" /ApplyDir:X: /Index:1 /WIMBoot

Rem 添加启动项至开机选单
bcdboot X:\windows /l zh-tw

:EXIT

============= 批处理结束!!! =================================================

6. 现在你可以从新开机看看是不是多了一个启动项了呢, 这个启动项就是采用WIMBOOT技术启动的

 

因为三文鱼简化了不少操作流程, 如果有甚么问题也请提出

比较容易遇到的问题是系统权限问题, 可以先关闭使用者帐户控制(UAC),然后在继续操作

附上开启跟关闭使用者帐户控制(UAC)的注册表, 将下面内容另存为 *.reg , 直接导入, 然后重新开机即可

============== 关闭使用者帐户控制(UAC).reg ====================================

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System]
"EnableLUA"=dword:00000000

==============注册表结束=================================================

============== 开启使用者帐户控制(UAC).reg ====================================

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System]
"EnableLUA"=dword:00000001

==============注册表结束=================================================

 

三文鱼这个人比较懒, 只介绍了能够顺利让新手用上WIMBOOT的方式

其实可以应用的方式更为广泛!! 技术资料参考自 无忧启动论坛