度分秒轉換十進位度之Excel實現

我們都知道，1°=60′，1′=60″，1°=3600″。
那麼，輕而易舉容易計算：112°18′37.6″=112+18/60+37.6/3600≈112.3104444°這當然是有參考價值的，比如爬下一張只有度分秒形式的經緯度表格，但是，我們的GIS軟體只認十進位度（原因無非就是十進位好算），那麼通過Excel的字元串操作函數，就可以輕鬆轉換為十進位度。

一、預備知識（三個函數）

1 FIND()函數

FIND函數可以找到某個字元（串）在指定字元串的哪裡。

我們說，CHINA中字母N在第4個，那麼

4=FIND("N","CHINA")

如果CHINA在單元格A1，那麼

4=FIND("N",A1)

// FIND函數還有第三個參數，此處不討論

即得出結論：

I = FIND(S,D) I——S在D的位置 S——查找的字元()串 D——被查找的字元串

2 LEFT()函數

LEFT()函數可以獲取從左邊開始數的第n個字元，通俗點講就是在第n個處切開，前n個留下形成結果字元串，其他的扔了。即：

LEFT("CHINA", 3)="CHI" LEFT("CHINA", 1)="C"

3 MID()函數

與LEFT類似，從左往右第i個起算，取j個，頭和尾不要了。

MID("CHINA",3,2)="IN" MID("CHINA",1,4)="CHIN"

二、提取度&分&秒的數值

OK，有了上部分的預備，那麼我們就要對[112°18′37.6″]中括弧內的字元串進行切割，把度分秒分別切出來。

首先，我們要獲取°號、′號、″號的位置：

A1=112°18′37.6″ A2=FIND("°", A1) //結果是4 A3=FIND("′", A1) //結果是7 A4=FIND("″", A1) //結果是12,小數點也佔一位字元

然後，使用LEFT取到度（注意是到°號之前的2，不是到度號）：

B1=LEFT(A1,A2) //結果錯誤，是112°，並不是我們想要的112 B1=LEFT(A1,A2-1) //結果是112

用MID取到分的數值。

注意，起點不是°號了，是度號往右一個，即A2+1。

要取多少個數字呢？這裡分的數值是兩位，則A3-A2-1剛好是2：

B2=MID(A1,A2+1,A3-A2-1) //結果是18

用MID取到秒的數值（起點數字，和取長，與分的數值同理）：

B3=MID(A1,A3+1,A4-A3-1) //結果是37.6

如果不太能理解A3-A2-1為啥剛好是分的數值的位數，自己稍微動一下腦筋就想出來了，用位數的順序相減唄。

三、拼接

這一步就簡單了，使用簡單的數學四則運算：

C1=B1+B2/60+B3/3600 //結果是112.3104444

四、整合所有公式到一個單元格

分步列公式是為了清晰過程，實際只需要一個單元格就可以計算，總結一下：

十進位度 =取度+取分/60+取秒/3600 =B1 + B2/60 + B3/3600 =LEFT(A1,A2-1) + MID(A1,A2+1,A3-A2-1) + MID(A1,A3+1,A4-A3-1) =LEFT(A1, FIND("°", A1)-1) + MID(A1, FIND("°", A1)+1, FIND("′", A1)-FIND("°", A1)-1)/60 + MID(A1, FIND("′", A1)+1, FIND("″", A1)-FIND("′", A1)-1)/3600

如果不寫成換行，那麼結果就會是：

=LEFT(A1, FIND("°", A1)-1) + MID(A1, FIND("°", A1)+1, FIND("′", A1)-FIND("°", A1)-1)/60 + MID(A1, FIND("′", A1)+1, FIND("″", A1)-FIND("′", A1)-1)/3600

如下圖所示：